/^[0-9][0-9]*$/ {
	curscreen = 0 + $1;
	nlines[curscreen] = 0;
	next;
}
{
	lines[curscreen "," nlines[curscreen]] = $0;
	nlines[curscreen] ++;
}
END {
	if (nlines[curscreen] == 0) curscreen --;
	nscreens = curscreen + 1;
	printf("int nhelpscreens = %d;\n",nscreens);
	maxnl = 0;
	for (i=0;i<nscreens;i++)
	{
		if (nlines[i] > maxnl) maxnl = nlines[i];
	}
	printf("int helpmaxnl = %d;\n",maxnl);
	printf("int helpmaxmw;\n");
	printf("int helpnlines[] = {");
	for (i=0;i<nscreens;i++)
	{
		printf(" %d,",nlines[i]);
	}
	printf(" };\n");
	printf("const char *helpscreens[] = {\n");
	for (i=0;i<nscreens;i++)
	{
		printf("\"\\\n");
		for (j=0;j<nlines[i];j++)
		{
			l = lines[i "," j];
			if ((l ~ /\\/) || (l ~ /"/))
			{
				len = length(l);
				for (k=1;k<=len;k++)
				{
					s = substr(l,k,1);
					if ((s == "\\") || (s == "\""))
					{
						printf("\\%s",s);
					}
					else
					{
						printf("%s",s);
					}
				}
				printf("\\n\\\n");
			}
			else
			{
				printf("%s\\n\\\n",l);
			}
		}
		printf("\",\n");
	}
	printf("};\n");
}